# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7
inherit savedconfig toolchain-funcs

DESCRIPTION="speedie's fork of suckless dmenu with color support and more."
HOMEPAGE="https://speedie.gq/projects/spmenu.php"

if [[ ${PV} == 9999 ]]; then
	inherit git-r3
	EGIT_REPO_URI="https://codeberg.org/speedie/${PN}.git"
else
	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~x86"
	SRC_URI="https://codeberg.org/speedie/${PN}/releases/download/${PV}/${P}.tar.gz"
fi

LICENSE="MIT"
SLOT="0"
IUSE="+xinerama +tcc"

RDEPEND="
	media-libs/fontconfig
	x11-libs/libX11
	x11-libs/libXft
	x11-apps/xrdb
	x11-libs/libXrender
	xinerama? ( x11-libs/libXinerama )
	media-libs/imlib2
	media-libs/freetype
	x11-libs/pango
	tcc? ( dev-lang/tcc )
"
DEPEND="${RDEPEND}
	x11-base/xorg-proto
"
BDEPEND="virtual/pkgconfig"

src_prepare() {
	default

	restore_config options.h
}

src_compile() {
	if use tcc; then
		comp="tcc"
	else
		comp="$(tc-getCC)"
	fi
	emake CC="$comp" \
		"XINERAMAFLAGS=$(
			usex xinerama "-DXINERAMA $(
				$(tc-getPKG_CONFIG) --cflags xinerama 2>/dev/null
			)" ''
		)" \
		"XINERAMALIBS=$(
			usex xinerama "$( $(tc-getPKG_CONFIG) --libs xinerama 2>/dev/null)" ''
		)"
}

src_install() {
	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" install

	save_config options.h
}